오토핫키로 윈도우 볼륨 조절 단축키 만들기

---

윈도우 볼륨 조절 프로그램 다운로드

Volume Manager.exe

1.07MB

 

 

◎ 사용법

볼륨조절 : Ctrl + 방향키 상하

음소거 : Ctrl + 방향키 오른쪽

확인 : Ctrl + 방향키 왼쪽

---

 

윈도우는 볼륨 조절 단축키가 별도로 존재하지 않습니다.(아마) 맥과 윈도우를 같이 사용하고 있는 입장에서 볼륨 조절을 반드시 작업표시줄을 통해서 해야 하는 것은 굉장히 번거로운 과정이었지만 윈도우를 위해서 볼륨 조절 버튼이 있는 키보드를 별도로 구매하기에는 영 내키지 않았기 때문에 오토핫키를 이용하여 간단하게 단축키를 설정해 보았습니다.

 

 

1단계 : Ctrl + ↑, Ctrl + ↓ 키조합으로 음량 조절하기

 

코드는 굉장히 간결하게 구성할 수 있습니다. 'soundset'이라는 함수를 사용해 볼륨을 조절할 수 있으며 여기서는 버튼을 누를 때마다 5씩 볼륨을 높이고 낮출 수 있도록 코드를 구성했습니다. +5, -5는 각각 볼륨을 5만큼 올리거나 낮추라는 것으로 숫자를 변경시키면 음량 조절을 좀 더 세분화 하거나 단순화시킬 수 있습니다.

^Up::
soundset, +5
return

^Down::
soundset, -5
return

 

다만, 이렇게만 코드를 구성하면 음량은 정상적으로 변경되지만 변경된 후의 음량이 정확이 어느정도인지 파악을 하기가 쉽지 않기 때문에 시각적인 알림을 표시하도록 설정해 보았습니다.

 

2단계 : TrayTip으로 변경된 볼륨 확인하기

'soundget'이라는 함수를 활용하면 현재 볼륨, 컴포넌트 타입, 음소거 여부 등 음향 장치와 관련된 다양한 정보를 얻을 수 있는데, 이 정보를 'TrayTip'에 담아 음량 변화를 시각적으로 보이게 구성했습니다.

 

^Up::
soundset, +5
soundget, master_volume
TrayTip Volume Up, Volume : %master_volume%, 1, 1  ;알림음 on - 1, off - 17
return

^Down::
soundset, -5
soundget, master_volume
TrayTip Volume Down, Volume : %master_volume%, 1, 1
return

 

그 결과, 아래 그림과 같이 실시간으로 정보가 표기됩니다.

 

 

근데 볼륨이 소수점으로 표기되는게 영 거슬리기도 하고, 단축키를 연타하면 알림이 먹통? 또는 지연되는 상황이 발생하여 코드를 조금 수정하였습니다.

 

Setformat, float, 0.0

^Up::
HideTrayTip()
soundset, +5
soundget, master_volume
TrayTip Volume Up, Volume : %master_volume%, 1, 1  ;알림음 on - 1, off - 17
return

^Down::
HideTrayTip()
soundset, -5
soundget, master_volume
TrayTip Volume Down, Volume : %master_volume%, 1, 1
return

HideTrayTip() {
    TrayTip  ; Attempt to hide it the normal way.
    if SubStr(A_OSVersion,1,3) = "10." {
        Menu Tray, NoIcon
        Sleep 200  ; It may be necessary to adjust this sleep.
        Menu Tray, Icon
    }
}

 

'Setformat'이라는 함수는 숫자 형식을 지정하는 것이고, 'HideTrayTip' 이라는 함수는 오토핫키 도움말에 친절하게 복사해서 사용하라고 적혀있는데 그냥 TrayTip 이라고만 사용하는 것과 차이점을 느낄 수 없었습니다. (내용에는 윈도우 10에서 중복된 알림을 제거하는데 효과적이라는 것 같은데 체감은...) 그래도 일단 챙겨주니까 써보는 것으로!

 

 

최종 코드

하는 김에 음소거 버튼도 추가하고 시작 시 단축키 안내도 추가하여 봤습니다.

#SingleInstance, force ;프로그램 중복 실행 방지
#Persistent ;프로그램 종료 방지
Setformat, float, 0.0

Menu, tray, NoStandard 
Menu, tray, DeleteAll
Menu, tray, add, Tip
Menu, tray, add, Blog
Menu, tray, add, Exit
Menu, tray, tip,Volume Manager


Tip:
message = 
(
volume_up : ctrl + up
volume_down : ctrl + down
mute_all : ctrl + right
)
TrayTip Volume Manager, %message%, 3, 17
return


^Up::
HideTrayTip()
soundset, +5
soundget, master_volume
TrayTip Volume Up, Volume : %master_volume%, 1, 1  ;알림음 on - 1, off - 17
return

^Down::
HideTrayTip()
soundset, -5
soundget, master_volume
TrayTip Volume Down, Volume : %master_volume%, 1, 1
return

^Right::
HideTrayTip()
soundset, +1, , mute
soundget, master_mute, , mute
TrayTip Volume Mute, Status : %master_mute%, 1, 17
return

^Left::
HideTrayTip()
soundget, master_volume
soundget, master_mute, , mute
message = 
(
Mute : %master_mute%
Volume : %master_volume%
)
TrayTip Volume Status, %message%, 1, 17
return


Exit:
ExitApp


HideTrayTip() {
    TrayTip  ; Attempt to hide it the normal way.
    if SubStr(A_OSVersion,1,3) = "10." {
        Menu Tray, NoIcon
        Sleep 200  ; It may be necessary to adjust this sleep.
        Menu Tray, Icon
    }
}


Blog:
Run, https://tae-di.tistory.com/
return

 

추가 : Ctrl + Shift 버전 다운로드

간혹 다른 프로그램 단축키와 겹치는 부분이 생겨 쉬프트 키를 키 조합에 추가한 버전도 만들어 봤습니다.

 

Volume Manager (+Shift).exe

1.07MB

 

 

◎ 사용법

볼륨조절 : Ctrl + Shift + 방향키 상하

음소거 : Ctrl + Shift + 방향키 오른쪽

확인 : Ctrl + Shift + 방향키 왼쪽

 

 

프로그램 종료

프로그램 종료는 작업표시줄 하단 오른쪽 아이콘 목록에서 아래와 같은 아이콘을 우클릭하여 'Exit'버튼을 클릭해 주시면 됩니다.

 

 

 

시작프로그램 설정 방법

2021/02/08 - [Study/Win] - 윈도우 10 시작프로그램 설정 및 해제 방법

윈도우 10 시작프로그램 설정 및 해제방법

위 링크에 시작프로그램 설정 방법이 안내되어 있으니 필요하신 분은 참고 부탁드립니다. 감사합니다.